Problème IPCop et wpkg

[Franky05]

Bonjour à tous,

Puisque nouvel utilisateur d'IPCop, je me présente : Frank, 35 ans, prof de maths et responsable réseau de mon établissement.

Voilà, pendant les grandes vacances j'ai décidé de revoir le réseau informatique que j'avais fait pour mon lycée :

- Avant : Internet ----- Modem/routeur ----- SME server ----- Windows Server 2003 (PDC) -----Postes clients.

- Maintenant : Internet ----- Modem/routeur ----- IPCop ----- Sambaedu3 (PDC) ----- Postes clients.

Jai configuré IPCop de la manière suivante : Orange + Green + Red (avec trois plages IP différentes bien entendu)

Mon serveur Sambaedu3 me sert de contrôleur de domaine, serveur de fichiers, etc etc. Ce dernier comporte des modules instables via l'interface web ou en ligne de commande et en particulier un module qui s'appelle WPKG. Ce module sert à déployer des applications (firefox, open office, ......) de manière automatique sur les postes clients. Le module WPKG se décompose en deux parties : une installation sur le serveur (aucun soucis) et exécution d'un fichier wpkg-config.bat sur un seul poste client et ce une seule fois mais c'est là que ça coince ! Le script bat charge le serveur d'écrire un fichier dans le répertoire local du poste client et c'est là que ça bloque. Impossible d'écrire ce fichier dans wpkg client ne s'installe pas donc impossible pour moi de faire du déploiement d'applications.

J'ai refait les tests en zappant ipcop : Internet ------ Sambaedu3 ------ postes clients et là nikel tout fonctionne, l'installation est possible sur le poste client.

Donc ma question est : au sein de l'interface verte, est-il possible qu'ipcop bloque le dialogue entre les PC ? ou sur certains ports ? pour prévenir d'éventuelles contaminations virales par exemple ?

J'ai regardé dans l'interface d'ipcop mais je ne sais pas trop quoi toucher....

Si vous avez une piste, je suis preneur !!

Très cordialement.

Frank.

[Gaston]

Bonjour,
je ne connais pas les solutions que tu mets en place, mais la description de ton problème démontre que l'exécution du batch sur le poste client déclenche une communication avec le serveur edu3, qui est bloqué par IPCop.

La "bonne" raison que je verrai à cela est que la communication essaie d'accéder de Green à RED

Tu devrais pouvoir modifier le batch pour logger ce qu'il exécute exactement
As tu essayer de capturer les trames sur les différentes interfaces pour vérifier que la communication passe bien par où tu le désires ?
As tu vérifié quelles sont les infos DNS utilisées sur les client et le serveur ?

G.
PS : complète ton schéma avec les @IP/masque sur les 3 interfaces, ça permettra de lever tous doutes à ce sujet

[Franky05]

Merci Gaston d'essayer de m'aider !!

Alors schéma complété :


Internet : abonnement pro orange IP fixe (en PPPoA d'où impossibilité de bridger pour IPCop)

Modem/routeur : IPLan -->192.168.0.1

IPCop : - interface rouge : IP statique = 192.168.0.2/255.255.255.0
- interface verte : IP = 192.168.1.1/255.255.255.0
- interface orange : IP = 192.168.2.1/255.255.255.0

Serveur Sambaedu3 : IP fixe = 192.168.1.2/255.255.255.0 ; DNS = orange mon fai ; passerelle = interface verte soit 192.168.1.1

Poste client : IP = obtenue par DHCP du serveur sambaedu3 ; DNS = interface verte soit 192.168.1.1 ; WINS = IP du sambaedu avec netbios activé sur TCP/IP.

Voilà, j'espère que jusqu'ici mon installation n'est pas foireuse....

Concernant le batch, voilà son contenu :

Code: Tout sélectionner

@echo off
:: Configuration de wpkg par l'admin.
::
:: Ce fichier fait partie du module se3-wpkg du projet SambaEdu.
::     Jean Le Bail - Octobre 2007
::
:: ## : wpkg-install.sh 3081 2008-07-03 21:55:03Z jlebail $ ##

echo.
echo  ######################################################
echo  #      CONFIGURATION DE WPKG pour votre r‚seau.      #
echo  #                                                    #
echo  #    WPKG permet de d‚ployer automatiquement         #
echo  #    des applications sur les PC Windows XP          #
echo  #    et Windows 2000 qui ont rejoint le domaine.     #
echo  #                                                    #
echo  ######################################################
echo.

Set REPONSE=O
Set /P REPONSE=  Voulez-vous configurer wpkg maintenant ? O^|N [%REPONSE%]
if Not "%REPONSE%"=="O" if Not "%REPONSE%"=="o" Goto TCHAO
Goto CESTPARTI

:TCHAO
echo.
echo             Une autre fois peut-^tre ...
Goto Done

:CESTPARTI
echo.
echo             C'est parti ...
echo.

Set WPKGROOT=\\se3\install\wpkg
Set SCHTASKEXE=%WinDir%\system32\schtasks.exe
Set DestExe=%WPKGROOT%\tools\schtasks2k.exe

Set WinType=XP
ver | find "2000" >NUL
if Not ErrorLevel 1 Set WinType=2K
if ErrorLevel 1 ver | find /I "XP" >NUL
if ErrorLevel 1 Goto No2000XP

:: Utilitaire schtasks2k.exe pour gerer les 'taches planifiees' sur Win2K et WinXp
Set SCHTASKS=schtasks2k
If Not Exist %WPKGROOT%\tools\schtasks2k.exe Goto MAKESCHTASKS2K
echo %WPKGROOT%\tools\schtasks2k.exe `tait d`j... disponible.
If "%WinType%"=="XP" echo Si vous souhaitez reg‚n‚rer schtasks2k.exe,
If "%WinType%"=="XP" echo   effacez-le puis relancez wpkg-config.bat.
echo.
Goto JTorSCHTASKS2KOK
:MAKESCHTASKS2K
:: Creation de schtasks2k.exe a partir de %WinDir%\system32\schtasks.exe
:: Est-on bien sur un WinXP
if "%WinType%"=="XP" Goto OnXP
:: Sinon, est-ce que jt.exe est disponible pour installer une tache planifiee
if Not Exist %WPKGROOT%\tools\jt.exe Goto NOJT
Set SCHTASKS=jt
Goto JTorSCHTASKS2KOK

:OnXP
Set SCHTASKS=
echo Application d'un patch ... schtasks.exe pour le rendre utilisable sous Windows 2000.
:: ----------------------------- patch schtasks.exe ---------------------------------------

:: Hack honteux pour rendre schtasks.exe de WinXP utilisable sous Win2k
:: D'apres une idee de http://www.windowsitpro.com/Articles/ArticleID/25186/25186.html
:: Adaptatation a la version francaise de schtasks.exe version 5.1.2600.2180
:: et automatisation de l'application du patch avec debug.

If Not Exist "%SCHTASKEXE%" Goto NoSCHTASKEXE

::Changement de repertoire
pushd %SystemDrive%\

copy /Y /B "%SCHTASKEXE%" .\schtasks.dat >NUL
If ErrorLevel 1 Goto ErrDupExe

:: S'agit-il de la bonne version du fichier
echo d e4f0 e4ff>patch1.txt
echo q>>patch1.txt

cmd /c debug schtasks.dat < patch1.txt >sortie.txt
type sortie.txt | find "00 E8 68 EC FF FF 85 C0-75 0F 68 7F 15 00 00 E8" >NUL

If ErrorLevel 1 Goto BadFile

:: Changement octet e4f8 : 75->EB
::    1535:E4F8 750F          JNZ     E509
:: a remplacer par
::    1535:E4F8 EB0F          JMP     E509

echo e e4f8 eb>patch2.txt
echo w>>patch2.txt
echo q>>patch2.txt
cmd /c debug schtasks.dat < patch2.txt

If ErrorLevel 1 Goto ErrDebug

:: Juste pour verifier le bon changement de l'octet.
cmd /c debug schtasks.dat < patch1.txt >sortie.txt
type sortie.txt | find "00 E8 68 EC FF FF 85 C0-EB 0F 68 7F 15 00 00 E8" >NUL

If ErrorLevel 1 Goto PatchNotDone
Echo Le patch a ‚t‚ appliqu‚ avec succŠs.

:: Recopie de ce fichier sur le serveur
copy /Y /B schtasks.dat %DestExe% >NUL
If ErrorLevel 1 Goto ErrCopy

Goto PatchDone

:ErrDupExe
Echo Erreur de copie de "%SCHTASKEXE%" vers "%SystemDrive%\schtasks.dat"
Goto ErreurPatch

:ErrCopy
Echo Erreur de copie de "%SystemDrive%\schtasks.dat" vers %DestExe%
Goto ErreurPatch

:PatchNotDone
Echo Erreur : l'application du patch a ‚chou‚ !
Goto ErreurPatch

:ErrDebug
Echo Erreur : La commande DEBUG a quitt‚ avec l'erreur %ErrorLevel% !
Goto ErreurPatch

:BadFile
Echo Erreur : le fichier %SCHTASKEXE% n'est pas de la version 5.1.2600.2180
Goto ErreurPatch

:NoSCHTASKEXE
echo Erreur : le fichier %SCHTASKEXE% n'existe pas !
echo Etes-vous bien sur un Windows XP ?
Goto ErreurPatch

:ErreurPatch
Set Erreur=1

:PatchDone
:: Faire du menage
If Exist patch1.txt del /F /Q patch1.txt 2>NUL >NUL
If Exist patch2.txt del /F /Q patch2.txt 2>NUL >NUL
If Exist sortie.txt del /F /Q sortie.txt 2>NUL >NUL
If Exist schtasks.dat del /F /Q schtasks.dat 2>NUL >NUL
popd
:: Saut hors patch en cas d'erreur
If "%Erreur%"=="1" Goto PatchFail
Goto SCHTASKS2KOK

:: Yeh ! we got it !
:: ----------------------------- Fin patch schtasks.exe ---------------------------------------

:PatchFail
echo Erreur : L'application du patch au fichier SCHTASKEXE a echou‚.
echo Vous pouvez tenter d'ex‚cuter … nouveau ce script … partir d'un autre PC (Windows XP SP2).
If Exist %WPKGROOT%\tools\jt.exe Goto JtEstLa
Goto RECOMMANDEJT

:SCHTASKS2KOK

Set SCHTASKS=schtasks2k
echo %DestExe% est maintenant disponible.

:JTorSCHTASKS2KOK
echo.
echo Essai de %WPKGROOT%\tools\schtasks2k.exe
echo   en listant les 'tƒches planifi‚es' actuelles de ce poste :
%DestExe%
echo.
if ErrorLevel 1 Echo %DestExe%
if ErrorLevel 1 Echo   a g‚n‚r‚ une erreur : ErrorLevel=%ErrorLevel%
if ErrorLevel 1 Echo.

:: Presence jt.exe
If Exist %WPKGROOT%\tools\jt.exe Goto JtEstLa
:RECOMMANDEJT
echo Vous devriez t‚l‚charger l'utilitaire jt.exe … l'adresse :
echo   ftp://ftp.microsoft.com/reskit/win2000/jt.zip
echo   Et placer aprŠs d‚compression jt.exe dans %WPKGROOT%\tools
echo Ainsi, vous n'aurez plus besoin du fichier patch` schtasks2K.exe.
echo Il vous faudra ensuite relancer ce script.
echo.
pause
Goto SetACL
:JtEstLa
Echo L'utilitaire jt.exe est disponible.
echo   Il sera utilis` pour cr‚er la tƒche planifi‚e.
echo.

:SetACL
Set SetACL=%WPKGROOT%\tools\SetACL.exe
If Exist %SetACL% Goto SetACLOK
echo Vous devriez t‚l‚charger l'utilitaire SetACL … l'adresse :
echo   http://ovh.dl.sourceforge.net/sourceforge/setacl/setacl-cmdline-2.0.2.0-binary.zip
echo   Et placer aprŠs d‚compression SetACL.exe dans %WPKGROOT%\tools
echo.
Goto CreationJob
:SetACLOK
echo L'utilitaire SetACL.exe est disponible
echo.

:: Recopie de reg.exe qui n'est pas disponible sous Win2k alors qu'il fonctionne parfaitement
If Exist %WinDir%\system32\reg.exe xcopy /Y /C /I /H /R %WinDir%\system32\reg.exe "%WPKGROOT%\tools\" >NUL
If Exist "%WPKGROOT%\tools\reg.exe" Echo L'utilitaire reg.exe est disponible dans %WPKGROOT%\tools\
If Not Exist "%WPKGROOT%\tools\reg.exe" Echo L'utilitaire reg.exe n'est pas disponible
echo.

:CreationJob
If Exist "\\se3\install\wpkg\wpkg.job" Del /F /Q "\\se3\install\wpkg\wpkg.job"

echo Cr‚ation du job CPAU d'install sous le compte adminse3
echo \\se3\Progs\ro\wpkgInstall.job
If Exist "\\se3\Progs\ro\wpkgInstall.job" Del /F /Q "\\se3\Progs\ro\wpkgInstall.job"
set TASK="(net use \\se3||(exit 8))&&(Set APPENDLOG=1&&Set TaskUser=adminse3&&Set TaskPass=adminse3local&&call \\se3\install\wpkg\wpkg-install.bat&net use * /delete /y)"

@If "0"=="1" Echo Dbg. TASK="(net use \\se3||(exit 8))&&(Set APPENDLOG=1&&Set TaskUser=adminse3&&Set TaskPass=adminse3local&&call \\se3\install\wpkg\wpkg-install.bat&net use * /delete /y)"

@\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgInstall.job -lwp -c -ex %TASK% 2>NUL >NUL
Set TASK=
If ErrorLevel 8 Goto ErrAuthSe3
If ErrorLevel 1 Goto ErrMakeInstallJob
If Not Exist "\\se3\Progs\ro\wpkgInstall.job" Goto ErrMakeInstallJob
echo \\se3\Progs\ro\wpkgInstall.job : SUCCES.

echo.
echo Cr‚ation du lien de lancement manuel de wpkg
Set TASKRUNWPKG="{%%{ComSpec}%%} /C cscript {%%{Windir}%%}\\wpkg-client.vbs /debug /notempo /cpuLoad 80&pause"
@\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgRun.job -lwp -c -ex %TASKRUNWPKG% 2>NUL >NUL
%WPKGROOT%\tools\nircmdc.exe shortcut \\se3\Progs\install\installdll\CPAU.exe "~$folder.desktop$" "Synchronise les applications Wpkg" "-dec -lwp -cwd c:\ -file \\se3\Progs\ro\wpkgRun.job" %%windir%%\system32\setup.exe
%WPKGROOT%\tools\nircmdc.exe execmd If Exist "~$folder.desktop$\Applications Wpkg.lnk" Del /f /S "~$folder.desktop$\Applications Wpkg.lnk"
%WPKGROOT%\tools\nircmdc.exe execmd RENAME "~$folder.desktop$\Synchronise les applications Wpkg.lnk" "Applications Wpkg.lnk"

:: echo.
:: echo Cr‚ation du lien pour forcer la valeur running=false
:: Set wpkgRunningFalseJOB=\\se3\Progs\ro\wpkgRunningFalse.job
:: @\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file "%wpkgRunningFalseJOB%" -lwp -c -ex "\\se3\install\wpkg\tools\reg.exe ADD HKLM\Software\wpkg /v running /d false /f" 2>NUL >NUL
:: %WPKGROOT%\tools\nircmdc.exe shortcut \\se3\Progs\install\installdll\CPAU.exe "\\se3\Progs\ro" "WpkgRunningFalse" "-dec -lwp -cwd c:\ -file %wpkgRunningFalseJOB%" %%windir%%\regedit.exe

echo.
echo Cr‚ation du job pour lancer wpkg-repair.bat
Set wpkgRepairJOB=\\se3\Progs\ro\wpkg-repair.job
Set wpkgRepairBAT=\\se3\install\wpkg\wpkg-repair.bat
@\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file "%wpkgRepairJOB%" -lwp -c -ex "(net use \\se3||exit 8)&&(set TaskUser=adminse3&&set TaskPass=adminse3local&&call %wpkgRepairBAT%&net use * /delete /y)" 2>NUL >NUL


:: --------------Install client sur poste local------------------------------
:: Controle du compte adminse3
net user adminse3 2>NUL >NUL
If ErrorLevel 1 Goto NoAdminse3
net user adminse3 | find "Compte" | find "actif" | find "Oui" 2>NUL >NUL
If ErrorLevel 1 Goto NoAdminse3Actif
net user adminse3 | find "*Administrateurs" 2>NUL >NUL
If ErrorLevel 1 Goto NoAdminse3Admins
net user adminse3 | find "mot de passe expire" | find "Jamais" 2>NUL >NUL
If ErrorLevel 1 Goto NoAdminse3NoExpire
echo.
echo Le compte adminse3 est actif, membre du groupe 'Administrateurs'
echo    et son mot de passe n'expire jamais.
Goto AskInstallLocal

:NoAdminse3NoExpire
echo.
echo Le mot de passe de adminse3 va expirer :
net user adminse3 | find "Le mot de passe expire"
pause
Goto AskInstallLocal

:NoAdminse3Admins
echo.
echo Le compte de adminse3 n'est pas membre du groupe des 'Administrateurs'.
pause
Goto LOGONBAT

:NoAdminse3Actif
echo.
echo Le compte local adminse3 n'est pas actif.
echo   Le test de la proc‚dure d'installation de wpkg n'est pas possible sur ce poste.
pause
Goto LOGONBAT

:NoAdminse3
echo.
echo Le compte local adminse3 n'existe sur ce poste.
echo   Ce poste n'a vraisemblablement pas rejoint le domaine...
echo   Le test de la proc‚dure d'installation de wpkg n'est pas possible sur ce poste.
pause
Goto LOGONBAT

:AskInstallLocal
Set REPONSE=O
echo.
echo Avant de placer la commande d'installation dans le script de login,
echo vous pouvez tester le script d'installation de wpkg sur ce poste.
echo.
echo Rmq. Les fenˆtres qui s'ouvrent pour ce test, seront masqu‚es
echo      lors de l'installation 'normale' au login d'un utilisateur.
echo.

Set NoRunWpkgJS=1
Set /P REPONSE=  Voulez-vous installer maintenant wpkg sur ce poste ? O^|N [O]
if Not "%REPONSE%"=="O" if Not "%REPONSE%"=="o" Goto LOGONBAT
Set NoRunWpkgJS=0
echo.
echo Installation de wpkg sur ce poste : en cours...
echo Pas de temporisation avant lancement de wpkg-se3.js > "%SystemDrive%\netinst\wpkg-notempo.txt"
::start /wait \\se3\Progs\install\installdll\CPAU.exe -dec -lwp -wait -outprocexit -cwd %SystemDrive%\ -file \\se3\Progs\ro\wpkgInstall.job
start /wait \\se3\Progs\install\installdll\CPAU.exe -dec -lwp -wait -cwd %SystemDrive%\ -file \\se3\Progs\ro\wpkgInstall.job
If "%ErrorLevel%"=="0" Goto InstallWPKGSucces
Goto ErrRunJob
:InstallWPKGSucces
Set WpkgIsInstalled=1
echo Installation de wpkg sur ce poste : SUCCES.
If "%NoRunWpkgJS%"=="1" Goto LOGONBAT
echo.
If Exist %WinDir%\wpkg.txt echo   %WinDir%\wpkg.txt : Etat des applis wpkg de ce poste.
If Exist %WinDir%\wpkg.log echo   %WinDir%\wpkg.log : Log de l'ex‚cution de wpkg-se3.js
If Not Exist %WinDir%\wpkg.txt echo  Err. %WinDir%\wpkg.txt absent : Pas d'‚tat des applis disponibles.
If Not Exist %WinDir%\wpkg.log echo  Err. %WinDir%\wpkg.log : Pas de Log de l'ex‚cution de wpkg.
If Exist %WPKGROOT%\rapports\%COMPUTERNAME%.txt echo   %WPKGROOT%\rapports\%COMPUTERNAME%.txt : Remont‚e serveur.
If Exist %WPKGROOT%\rapports\%COMPUTERNAME%.log echo   %WPKGROOT%\rapports\%COMPUTERNAME%.log : Remont‚e serveur.
If Not Exist %WPKGROOT%\rapports\%COMPUTERNAME%.txt echo  Err. %WPKGROOT%\rapports\%COMPUTERNAME%.txt absent : Pas de Remont‚e sur le serveur.
If Not Exist %WPKGROOT%\rapports\%COMPUTERNAME%.log echo  Err. %WPKGROOT%\rapports\%COMPUTERNAME%.log absent : Pas de Remont‚e sur le serveur.
pause
:: --------------Fin Install client sur poste local------------------------------

:LOGONBAT
:: ------------------Insert Installwpkg dans \\se3\admhomes\templates\base\logon.bat------------------------------
echo.
echo.
echo Commande … ajouter sur une ligne au script de login des utilisateurs :
echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
echo @if "%%OS%%"=="Windows_NT" if not exist "%%WinDir%%\wpkg-client.vbs" \\se3\Progs\install\installdll\CPAU.exe -dec -lwp -hide -cwd %%SystemDrive%%\ -file \\se3\Progs\ro\wpkgInstall.job 2^>NUL ^>NUL
echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
echo.
If not exist \\se3\admhomes\templates\base\logon.bat goto NoLogonBat

echo Contenu actuel du script de login concernant 'wpkg' :
echo -------- extrait de \\se3\admhomes\templates\base\logon.bat -------
find /V "#" \\se3\admhomes\templates\base\logon.bat | find /V "Rem " | find /V "::" | find /I "wpkg"
echo -------------------------------------------------------------------
echo.
If ErrorLevel 1 Goto PASCMDLOGIN
find "@if ""%%OS%%""==""Windows_NT"" if not exist ""%%WinDir%%\wpkg-client.vbs"" \\se3\Progs\install\installdll\CPAU.exe -dec -lwp -hide -cwd %%SystemDrive%%\ -file \\se3\Progs\ro\wpkgInstall.job 2>NUL >NUL" \\se3\admhomes\templates\base\logon.bat >NUL
If Not ErrorLevel 1 Goto SameCMD
echo Une commande d'installation de wpkg semble d‚j… pr‚sente dans logon.bat
echo   Elle n'est cependant pas identique … la commande pr‚conis‚e.
echo   Voulez-vous quand mˆme ajouter la commande d'installation de wpkg
Set REPONSE=N
Goto AskInsertCmd

:SameCMD
echo La commande qui se trouve dans le script co‹ncide avec la commande pr‚conis‚e.
pause
echo.
Goto WPKGOK

:PASCMDLOGIN
echo   Voulez-vous ajouter la commande d'installation de wpkg
Set REPONSE=O

:AskInsertCmd
Set /P REPONSE=  au template base logon.bat ? O^|N [%REPONSE%]
if Not "%REPONSE%"=="O" if Not "%REPONSE%"=="o" Goto NoAddTemplate
echo. >> \\se3\admhomes\templates\base\logon.bat
echo @if "%%OS%%"=="Windows_NT" if not exist "%%WinDir%%\wpkg-client.vbs" \\se3\Progs\install\installdll\CPAU.exe -dec -lwp -hide -cwd %%SystemDrive%%\ -file \\se3\Progs\ro\wpkgInstall.job 2^>NUL ^>NUL >> \\se3\admhomes\templates\base\logon.bat
echo.
echo Nouveau contenu du script de login concernant 'wpkg' :
find /I "wpkg" \\se3\admhomes\templates\base\logon.bat
echo.
If ErrorLevel 1 Goto NoInstallTemplate
:: -----------------Fin Insert Installwpkg dans \\se3\admhomes\templates\base\logon.bat------------------------------

:WPKGOK
find /I ":: Pour resoudre un probleme de lancement de wpkg" \\se3\admhomes\templates\base\logon.bat >NUL
If "%ErrorLevel%"=="0" Goto WPKGGreetings
echo. >> \\se3\admhomes\templates\base\logon.bat
echo :: Pour resoudre un probleme de lancement de wpkg sur un poste. >> \\se3\admhomes\templates\base\logon.bat
echo Rem @if "%%COMPUTERNAME%%"=="PosteProblemeWpkg" call \\se3\Progs\install\wpkg-diag.bat 2^>NUL ^>NUL  >> \\se3\admhomes\templates\base\logon.bat

:WPKGGreetings
echo.
echo F‚licitation : WPKG est op‚rationnel sur ce serveur
echo   Il sera install‚ puis execut‚ sur les postes
echo     au prochain login d'un utilisateur.
echo   Une fois install‚, WPKG s'ex‚cute au boot du poste,
echo     aprŠs une temporisation de 30sec,
echo     sans qu'il soit n‚cessaire de s'authentifier.
Goto AUTODEL

:ErrAuthSe3
echo.
echo Echec d'authentification au serveur se3 avec le compte 'se3\adminse3'.
Goto Done

:NoAddTemplate
echo.
echo F‚licitation : La configuration de Wpkg est termin‚e.
If "%InLoginScript%"=="1" Goto AUTODEL
echo   Il vous reste … ajouter la ligne de commande pr‚c‚dente
echo   dans les templates de votre choix.
Goto AUTODEL

:No2000XP
Set WinType=9x
echo Erreur : Vous n'ˆtes pas sur un poste Windows 2000 ou XP.
Goto Done

:ErrMakeInstallJob
echo Erreur : le fichier \\se3\Progs\ro\wpkgInstall.job n'a pas pu ˆtre cr‚.
Goto Done

:ErrRunJob
echo Erreur : l'installation de wpkg sur ce poste a ‚chou‚. Err=%ErrorLevel%
If EXIST "%SystemDrive%\netinst\wpkg-notempo.txt" del /F /Q "%SystemDrive%\netinst\wpkg-notempo.txt"
Goto Done

:NoLogonBat
echo Erreur : le fichier \\se3\admhomes\templates\base\logon.bat est introuvable.
Goto NoInstallTemplate

:NoInstallTemplate
echo Erreur : le fichier template \\se3\admhomes\templates\base\logon.bat n'a pas pu ˆ‹tre mis … jour.
echo Ajoutez manuellement la ligne pr‚c‚dente au script de login des utilisateurs.
Goto Done

:NOJT
echo.
echo Erreur : Vous n'ˆtes pas sur un PC Windows XP et l'utilitaire jt.exe
echo   n'est pas disponible.
echo   T‚l‚chargez jt.zip depuis l'adresse :
echo     ftp://ftp.microsoft.com/reskit/win2000/jt.zip
echo     puis, aprŠs extraction, placez le fichier jt.exe dans le r‚pertoire :
echo     %WPKGROOT%\tools\
echo   C'est ce que je vous recommande.
echo.
echo   Sinon, vous pouvez vous passer de jt.exe … condition d'ex‚cuter ce script
echo   … partir d'un PC Windows XP...
echo.
Goto Done

:AUTODEL
If Not Exist "%~f0" Goto Done
Set REPONSE=O
echo.
echo La gestion des applications … d‚ployer sur les postes,
echo   se fait … l'aide d'un navigateur web … l'adresse :
echo   http://192.168.1.2:909/wpkg/ 
echo.
echo Par s‚curit‚, il serait prudent de supprimer ce fichier de configuration.
echo    Pour cela, tapez : del %~f0 
echo.
echo    En cas de besoin, vous pourrez le recr‚er en ex‚cutant … nouveau
echo    '/var/cache/se3_install/wpkg-install.sh'
echo    en root, sur la console du serveur.
echo.

If Not "%WpkgIsInstalled%"=="1" Goto WpkgNotInstalled
If "%NoRunWpkgJS%"=="1" echo Wpkg s'ex‚cutera au prochain d‚marrage de ce poste.
If Not "%NoRunWpkgJS%"=="1" echo Wpkg s'ex‚cutera … nouveau … chaque d‚marrage de ce poste.
echo Si vous voulez ex‚cuter wpkg maintenant, utilisez le lien
echo    'Applications Wpkg' sur le bureau de %UserName%.
echo.
:WpkgNotInstalled

@If "0"=="1" Echo L'installation a ‚t‚ effectu‚e en mode DEBUG (DBG="1").
@If "0"=="1" Echo   Si tout s'est bien pass‚, n'oubliez pas de
@If "0"=="1" Echo   r‚executer ce script en mode normal (DBF="0")
@If "0"=="1" Echo   pour supprimer les 'Pause' de l'ex‚cution des scripts.
@If "0"=="1" Echo.

::set /P REPONSE=Voulez-vous supprimer wpkg-config.bat maintenant ? O^|N [O]
::if Not "%REPONSE%"=="O" if Not "%REPONSE%"=="o" Goto Done
::del "%~f0"&exit 0
Goto Done

:Done
Set DestExe=
Set REPONSE=
Set SCHTASKS=
Set SetACL=
Set WinType=
Set WpkgIsInstalled=
Set WPKGROOT=

echo.
echo Fin de wpkg-config.bat
Pause

Moi lorsque j'exécute ce batch, j'ai immanquablement le message suivant si IPCop est présent :

"Création du job CPAU d'install sous le compte adminse3 \\se3\Progs\ro\wpkginstall.job
Erreur le fichier \\se3\Progs\ro\wpkginstall.job n'as pas pu être créé"

Fin de wpkg-config.bat

Voilà, j'espère avoir été le plus précis possible.

Cordialement.

Frank.

[ccnet]

Donc ma question est : au sein de l'interface verte, est-il possible qu'ipcop bloque le dialogue entre les PC ? ou sur certains ports ? pour prévenir d'éventuelles contaminations virales par exemple ?

La réponse est évidement clairement non dans la mesure où toutes les machines connectées à green sont, normalement, dans le même domaine de broadcast ethernet, ce qui signifie qu'elles communiquent directement sans passer par l'interface d'ipcop. L'émission d'une requête arp doit recevoir une réponse de la machine destinataire de l'ip recherchée.

Je fais donc en gros la même déduction que Gaston. Il y a très probablement une erreur de configuration qui passe inaperçue (un masque, une paserelle, 192.168.1.2 ou 192.168.2.1, un chiffre qui manque, ...).

Il est bien entendu que les différentes interfaces d'ipcop sont connectées à des switchs (ou hubs) distincts ?

Sur un poste client, vous pouvez installer Wireshark et déclencher une capture juste avant le lancement du batch pour voir ce qui se passe vraiment sur le réseau.

[Gaston]

Bonjour,

"Création du job CPAU d'install sous le compte adminse3 \\se3\Progs\ro\wpkginstall.job
Erreur le fichier \\se3\Progs\ro\wpkginstall.job n'as pas pu être créé"

Donc tu plantes lors de l'usage d'un partage samba: est-ce qu'il a bien été réalisé ?
vérifier quel est ma valeur de 'se3' dans les deux configurations,
faire le net use à la main avec le nom 'se3' et essayer avec l'@IP 192.168.1.2
tracer ce qui se passe lorsque, à la main, tu lances le

Code: Tout sélectionner

@\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgInstall.job -lwp -c -ex %TASK%

(en ayant fait le set TASK avec le net use )
valeur de l'ERRORLEVEL ?

Modem/routeur : IPLan -->192.168.0.1

IPCop : - interface rouge : IP statique = 192.168.0.2/255.255.255.0
- interface verte : IP = 192.168.1.1/255.255.255.0
- interface orange : IP = 192.168.2.1/255.255.255.0

Serveur Sambaedu3 : IP fixe = 192.168.1.2/255.255.255.0 ; DNS = orange mon fai ; passerelle = interface verte soit 192.168.1.1

Poste client : IP = obtenue par DHCP du serveur sambaedu3 ; DNS = interface verte soit 192.168.1.1 ; WINS = IP du sambaedu avec netbios activé sur TCP/IP.

Je pense qu'il ya une erreur dans le dns de se3 : il ne devrait (enfin je pense) pas connaître le DNS Orange mais IPCop (qui lui le connait)

Et comme le précise ccnet seule l'utilisation d'une capture éclairera avec certitude qui fait quoi (pour le moment je ne travaille que sur une supposition -mais avec des informations claires néanmoins)

G.
PS ton script semble généré, attention à le regénerer quand tu changes de config (avec et sans IPCop, nom wins ou adresse IP, ...), que tu changes un seul paramètre, ça peut changer des choses, ailleurs que là où c'est évident

[Franky05]

Merci de votre gentillesse, c'est pas tous les jours que l'on rencontre cela.....

Alors dans l'ordre :

Il est bien entendu que les différentes interfaces d'ipcop sont connectées à des switchs (ou hubs) distincts ?

Pour être précis :

Internet ----- Modem/Routeur ----- IPCop ------ Switch ----- Interface verte (comme je n'ai encore rien mis sur l'interface Orange je n'est pas installé de switch dédié pour celle-ci mais pour être tout à fait honnête avec toi je ne savais pas qui fallait un switch dédié à chaque interface)

Sur un poste client, vous pouvez installer Wireshark et déclencher une capture juste avant le lancement du batch pour voir ce qui se passe vraiment sur le réseau.

Chose faite mais je me documente pour pouvoir interpréter les logs...

Donc tu plantes lors de l'usage d'un partage samba: est-ce qu'il a bien été réalisé ?
vérifier quel est ma valeur de 'se3' dans les deux configurations,
faire le net use à la main avec le nom 'se3' et essayer avec l'@IP 192.168.1.2

- service samba : /etc/init.d/samba stop ---> le service s'arrête et /etc/init.d/samba start ---> le service démarre

- commande net use : net use \\se3 et net use \\192.168.1.2 -----> la commande s'est terminée correctement.

tracer ce qui se passe lorsque, à la main, tu lances le
Code:
@\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgInstall.job -lwp -c -ex %TASK%
(en ayant fait le set TASK avec le net use )
valeur de l'ERRORLEVEL ?

C'est là que mes très faibles compétences (mais j'essaye de m'améliorer ) ne me permettent pas de comprendre ce dont tu me parles...Je ne sais pas ce qu'il faut faire à ce niveau là....

Je pense qu'il ya une erreur dans le dns de se3 : il ne devrait (enfin je pense) pas connaître le DNS Orange mais IPCop (qui lui le connait)

Je suis conscient que je ne devrais pas mettre cela dans les paramétrages DNS du se3 car je les ai déjà rentré dans IPCop mais si je ne le fais pas, c'est à dire si je donne au se3 ma passerelle (interface verte, c'est peut-être là que je me trompe ?? mais je ne pense pas qu'il faille donner la rouge...) en tant que DNS alors se3 n'a pas le net. Voilà pourquoi j'ai fait cela.

Très cordialement.

Frank.

[Franky05]

Rectification pour Gaston : j'ai mis l'ip de linterface verte d'IPCop dans le DNS primaire et le DNS secondaire du se3 et j'ai bien le net sur le se3.....désolé de la bêtise....

[Gaston]

Bonsoir,
ce qu'il faut c'est tracer où est le problème :
-en analysant les échanges entre IPCop, le serveur se3 (je rédusi le nbre de lettre à taper ) et entre le serveur se3 et le poste client, le post client et IPCop
- et en réduisant le nombre de requêtes à analyser

Ce qu'il semblait c'est que le problème se situait dans la ligne de commande que j'avais quotté, mais je commence à en douter.

Ma démarche (en parallèle de la capture)
vérifier que toutes les opérations attendues s'exécutent sans problème

Code: Tout sélectionner

net use \\se3 adminse3local /USER:adminse3
\\se3\install\wpkg\wpkg-install.bat

lancer la commande globale et vérifier le code retour

Code: Tout sélectionner

set TASK="(net use \\se3||(exit 8))&&(Set APPENDLOG=1&&Set TaskUser=adminse3&&Set TaskPass=adminse3local&&call \\se3\install\wpkg\wpkg-install.bat&net use * /delete /y)"
\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgInstall.job -lwp -c -ex %TASK%
echo %ERRORLEVEL%

je pense que cela va donner "1" ...

Rectification pour Gaston : j'ai mis l'ip de linterface verte d'IPCop dans le DNS primaire et le DNS secondaire du se3 et j'ai bien le net sur le se3.....désolé de la bêtise....

et ce changement a-t-il une incidence sur ton problème premier (en ayant regénéré le batch bien sur) ?

mais là je suis un peu sec sur le problème ...

G.[/code]

[Franky05]

Bonsoir,

C'est finalement grâce à ta dernière question que tout est rentré dans l'ordre !!! je m'explique : je t'ai dit que j'avais changé mes DNS sur le serveur (grâce à un script présent sur le serveur qui permet de changer l'ip, les dns, etc etc) mais je n'étais pas allé voir mon fichier resolv.conf dans lequel figurent DNS primaire et secondaire. Quand j'ai édité celui-ci, je me suis aperçu que le DNS secondaire de Orange (80.10.246.130) était encore présent alors que le primaire était bien en 192.168.1.1. J'ai remplacé celui-ci par l'ip "verte" d'ipcop et nikel tout fonctionne correctement !!

Bon, je ne suis pas encore au bout de mes peines puisque je rencontre d'autres soucis :

- installation des modules (style wpkg dont nous avons parlé) impossible à partir de l'interface web du serveur mais nikel par un apt-get sur la console....
- lenteur de l'ouverture de la session admin, 1min30s (et uniquement d'elle) sur les ordis équipés de cartes graphiques Nvidia (je ne suis pas le seul d'après ce que j'ai lu sur la liste de diffusion) et pas avec les cartes ATI....

Enfin, du boulot en perspective ! Mais comme tu ne "connais" pas vraiment (ou du tout) cette distrib, j'essaierai de poster aux bons endroits même si tes (vos) connaissances t'ont permis de cerner le problème.....

En tout cas merci beaucoup pour ton aide et celle de ccnet, j'avance lentement mais j'avance...Prochaine étape installation d'un serveur LCS sur l'interface orange

P.S. : penses-tu comme ccnet qu'il faille un switch dédié à chaque interface d'ipcop (orange, verte, bleue) ? Est-ce une question d'incapacité des switchs de distribuer l'info sur différentes plages d'IP ? une question de sécurité ? ou si un seul switch mon interface verte et ma orange n'arriveraient-elles pas à dialoguer ? Je me renseignerai de mon côté en tout cas.

P.S.2 : j'ai installé sur IPCop urlfilter, advproxy et BOT -----> suffisant ?

P.S.3 : par politesse, j'ai exécuté les commandes citées dans ton dernier post:

- net use \\se3 adminse3local /USER:adminse3 : me donne une erreur système 1219. Plusieurs connexions à un serveur ou une ressource partagée par le même utilisateur, en utilisant plus d'un nom d'utilisateur, ne sont pas autorisées. Je pense que c'est normal car adminse3 et adminse3local sont 2 comptes administrateurs différents, un du domaine et un du client en local (ce dernier compte est créé automatiquement par le script d'intégration au domaine du poste client)

- set TASK="(net use \\se3||(exit )&&(Set APPENDLOG=1&&Set TaskUser=adminse3&&Set TaskPass=adminse3local&&call \\se3\install\wpkg\wpkg-install.bat&net use * /delete /y)"
\\se3\Progs\install\installdll\CPAU.exe -u adminse3 -p adminse3local -enc -file \\se3\Progs\ro\wpkgInstall.job -lwp -c -ex %TASK%
echo %ERRORLEVEL% : me donne un joli "0" (mais me donnait un "1" avant modif des dns)

Cordialement.

Frank.

[ccnet]

PS : C'est une question de sécurité. Il est quasiment trivial d'accéder à une autre zone, sans passer par ipcop, dès lors qu'elle est sur le même réseau physique.

PS2 : suffisant oui, si ce n'est, comme je le répète régulièrement que le proxy et le filtrage d'url n'ont rien à faire sur le firewall.